/*******************************************************************************************************
 **   
 **  This program creates the following education variables for survey year 2019   
 **                                                                                 
 ** 	  variable name in	      variable name                                       
 ** 	   the program			      in the NLS                                          
 ** 	   ------------------------------------------------------                     
 ** 	     ENCAT			      CV_ENROLLSTAT                                           
 ** 	     GRSURV			      CV_HGC_EVER_EDT                                         
 ** 	     DEGSURV	          CV_HIGHEST_DEGREE_EVER_EDT                              
             GRSURV_CVC           CVC_HGC_EVER
             DEGSURV_CVC          CVC_HIGHEST_DEGREE_EVER                            

 *******************************************************************************************************/
/******** this program uses the same list of input variables as Date Received Diploma or Degree ********/
 
********************************************** SECTION I **********************************************;

** Initialize and define variables;

ENROLL=-3;    * Indicates if R currently enrolled;

ENCAT=-3;     * Enrollment status variable (including educational attainment);

HSD=0;        * Indicates if R has a H. S. Diploma (check previous rounds);

GED=0;        * Indicates if R has a GED (check previous rounds);

hgsch=0;      * Indicates if R is currently attending grades 1-12 & no HSD or GED;

college=0;    * Indicates if R is in college and working towards a undergrad (=1) or grad degree (=2);

attsch=0;     * Indicates if R attended elementary, middle or high school;

flagcoll=0;   * Indicates if Rs currently attending grades 1-12, no HSD or GED but enrolled in college 
                and working towards a grad or undergrad degree;

flaghs=0;     * Indicates if Rs who have a H.S. Diploma and HGC=12 but still report enrollment in school;

somecoll=0;   * Indicates if Rs have attended a college (in a degree program) in current or previous 
                rounds;

prevcoll=0;   * Indicates if Rs have attended a college (in a degree program) in previous rounds. This
                pertains to those actually enrolled in a degree program in college only;

currcoll=0;   * Indicates if Rs have attended a college (in a degree program) in current round. This 
                pertains to those enrolled in a college and reporting to be working towards a degree 
                program. They may or may not be enrolled in a degree program.;

clg_ok=-4;    * Indicates if R being in college (as reported in this round) w/o GED/HSD is OK. That is if
                R is actually enrolled in a degree program. This pertains to currcoll and not prevcoll.;

last_enr=0;   * Identifies the last round when R was enrolled;

ungraded=0;   * Indicates Rs with no H.S. Diploma or GED have HGA=95 (ungraded);

same_mth=0;   * Indicates Rs who received a degree in the same month as the interview.;

both=0;       * Indicates that R reports receiving both GED and H. S. Diploma;

rosprb1=0;    * Indicates Rs with scode(i) in (4,5) but e27337(i)=-4;

rosprb2=0;    * Indicates Rs with scode(i)=-4 but e27337(i)>-4;

rosprb3=0;    * Indicates cases where start and stop dates of enrollment and school codes are missing 
                from Roster although information is available in the data;
  
rosprb4=0;    * Indicates cases wherer stop dates of enrollment in the Roster is not the date of current 
                interview although R reports being continuously enrolled in that school;

rosprb5=0;    * Indicates a few special cases where the reason for leaving school were interchanged 
                between school loops 1 and 2;

fill=-4;      * These are filler variables that are used in arrays to match the number of elements.;

chk_comm=0;   * Indicates if R reports college in this round although R does not report receiving GED or 
                H.S. Diploma, by this round. Check the comments in current round to see whether they 
                were actually enrolled in a degree program in a college.;

chk_commP=0;  * Indicates if ENCAT in any prior rounds shows college although R does not report 
                receiving GED or HS Diploma, by those rounds. Check the comments in current and earlier
                rounds for these cases to see whether they were actually enrolled in a degree program in 
                a college.;

chk_hgc=0;    * Those who received a H.S. Diploma, but report HGA<=12 & HGC<12;

chk_grmon=0; * Indicate cases where GRSURV is coded with the GRSURV at DLI, i.e., grsurvP. In these 
                cases we must check whether that grade was completed by June of 2004 to ensure that 
                coding GRMON also by grsurvP is correct.;

hgc_hga=0;    * Indicates if Rs reporting HGC greater than HGA;

hgc_hga_n=-4; * Indicates if Rs reporting HGC greater than HGA, after HGC and HGA were edited for those
                never enrolled at or since DLI such that they remained the same as those at DLI.;

 **************************************************************
 ** dlicm:     date of last interview                        **
 ** dli_rnd:   the last round that R was interviewed         **
 ** doicm:     date of current interview                     **
 ** enroll_Rx: whether enrolled in earlier rounds            **
 ** encatP:    ENCAT when last interviewed                   **
 ** hgaloop:   highest grade attended (from loops)           **
 ** hgcloop:   highest grade completed (from loops)          **
 ** hgcdt:     date of completion of hgcloop                 **
 **************************************************************;

MONYR=476;
YEAR=2019;
MONTH=8;
doicm_LR=doicmr18;

*** Define arrays to be used later in the program;

array scode  (*) scoder19_1-scoder19_5;
array e27337 (*) e27337r19_1-e27337r19_5;
array e23450 (*) e23450r19_1-e23450r19_5;

array strtm  (*) strtmr19_11-strtmr19_15 strtmr19_21;
array strty  (*) strtyr19_11-strtyr19_15 strtyr19_21;
array stopm  (*) stopmr19_11-stopmr19_15 stopmr19_21;
array stopy  (*) stopyr19_11-stopyr19_15 stopyr19_21;
array degre  (*) e27337r19_1-e27337r19_5 e27337r19_1;
array codes  (*) scoder19_1-scoder19_5   scoder19_1; 
array reasn  (*) lftscr19_1-lftscr19_5   lftscr19_1; 

array strcm  (*) strcm11-strcm15 strcm21; 
array stpcm  (*) stpcm11-stpcm15 stpcm21; 

array gratnd   (*)  e8416r19_11 e8416r19_21 dum dum;
                    
array e6784 (*) e6784r19_1-e6784r19_4;
array e7142 (*) e7142r19_11 e7142r19_21 e7142r19_31 e7142r19_41;
array e7192 (*) e7192r19_1-e7192r19_4;
array e6938 (*) e6938r19_1-e6938r19_3 dum;
array e6943 (*) e6943r19_11 dum dum dum;

array doicmR   (*) doicmr1-doicmr18;
array encatR   (*) encatr1-encatr18;
array enrollR  (*) enrollr1-enrollr18;
array graugR   (*) hgcr1 hgcYr2-hgcYr18; 
array grsurvR  (*) hgcr1-hgcr17 cvc_hgcr18;
array hgaR     (*) e3500r1 e2857r2-e2857r18;
array hgcR     (*) e5000r1 e3112r2-e3112r18;
array gdR      (*) gdr1-gdr18; 
array hsR      (*) hsr1-hsr18;
array locaR    (*) dum locar2-locar18;
array chk31R   (*) chk31r1-chk31r18;
array chk32R   (*) chk32r1-chk32r18;
array chk1encR   (*) chk1encr1-chk1encr18; 
array chk1gedR   (*) chk1gedr1-chk1gedr18; 
array chk2R   (*) chk2r1-chk2r18;
array chk3R   (*) chk3r1-chk3r18;
array chk5R   (*) chk5r1-chk5r18;

array scoder  [18,8] scoder1_1-scoder1_2 dum dum dum dum dum dum 
                    scoder2_1-scoder2_6 dum dum
                    scoder3_1-scoder3_7 dum
                    scoder4_1-scoder4_5 dum dum dum
                    scoder5_1-scoder5_6 dum dum
                    scoder6_1-scoder6_5 dum dum dum
                    scoder7_1-scoder7_5 dum dum dum
                    scoder8_1-scoder8_5 dum dum dum
                    scoder9_1-scoder9_4 dum dum dum dum
                    scoder10_1-scoder10_5 dum dum dum
                    scoder11_1-scoder11_5 dum dum dum
					scoder12_1-scoder12_8
					scoder13_1-scoder13_3 dum dum dum dum dum
					scoder14_1-scoder14_5 dum dum dum
					scoder15_1-scoder15_4 dum dum dum dum
					scoder16_1-scoder16_4 dum dum dum dum
					scoder17_1-scoder17_4 dum dum dum dum
					scoder18_1-scoder18_6 dum dum;
                    
array degR (*) hdgr1-hdgr17 cvc_hdgr18;
 
*** initiate the cvc_ variables;
if e3112r19=-5 then do;
  grsurv=cvc_hgcr18;
  degsurv=cvc_hdgr18; 
end;

*** Create intermediate variables to be used in the program later.;

** Checking int dates;
doicmr19=-5;
if intyr19 ne -5 then doicmr19=(intyr19-1980)*12+intmr19;

if doicmr19~=-5 then doicm=doicmr19;

* Whether received GED, ever;
if CDTGD>-4 then GED=1;
* Whether received HS Diploma, ever;
if CDTHS>-4 then HSD=1;
* Whether received both GED and HS Diploma, ever;
if HSD=1 & GED=1 then both=1;

* Compute dlicm and dli_rnd;
do j=1 to dim(doicmR);
   if doicmR(j)~=-5 then do;
      dlicm=doicmR(j);
      dli_rnd=j;
      do k=1 to 8;
         if scoder(j,k) in (4,5) then ever_24yrinst=1;
      end;
   end;
end;
hsrp=hsr18; gdrp=gdr18;
if HSD=0 & hsrP>-4 then hsrP=-4;
if GED=0 & gdrP>-4 then gdrP=-4;

* Enrollment status at each interview and ENCAT at last interview;
do i=1 to dim(doicmR);
   if encatR(i) in (8,9,10,11) then enrollR(i)=1;
   if encatR(i) in (1,2,3,4,5,6,7) then enrollR(i)=0;
   if -5<encatR(i)<0 then enrollR(i)=encatR(i);
   if encatR(i)~=-5 then encatP=encatR(i);
   if encatR(i)~=-5 then enrollP=enrollR(i);
   if enrollR(i)=1 then last_enr=i;
   if hgaR(i) not in (-4, -5) then hgaP=hgaR(i); 
end;

** Create variable indicating HGC by DLI;
do i=1 to dim(graugR);
   if graugR(i)>-5  then graugP=graugR(i);
   if locaR(i)>-5 then locaP=locaR(i);
end;

grsurvP=cvc_hgcr18;
grsurvP_no3061=grsurvP; 
if 0<grsurvP<graugP<95 then graugP=grsurvP;
degsurvP=cvc_hdgr18;

** Start and stop dates of enrollment in continuous month scheme;
do i=1 to dim(degre);
   if stopm(i)>0 & stopy(i)>0 then stpcm(i)=((stopy(i)-1980)*12)+stopm(i);
   if -4<stopm(i)<0|-4<stopy(i)<0 then stpcm(i)=-3;
   if strtm(i)>0 & strty(i)>0 then strcm(i)=((strty(i)-1980)*12)+strtm(i);
   if -4<strtm(i)<0|-4<strty(i)<0 then strcm(i)=-3;
end;

** Data and quex problems w/ roster information;
rosprb1=0; rosprb2=0;
do i=1 to dim(scode);
   if scode(i) in (4,5,6) & e27337(i)=-4 then rosprb1=1;
   if scode(i)=-4 & e27337(i)>-4 then rosprb2=1;
   if scode(i) in (-2,-3) then INV1=1;
   if scode(i) in (4,5,6) & e27337(i) in (-2,-3) then INV2=1;
end;
do i=1 to dim(strcm);
   if strcm(i)=-3 then INV3=1;
   if stpcm(i)=-3 then INV3=2;
   if strcm(i)=-3 & stpcm(i)=-3 then INV3=3;
end;

* Last regular school enrolled in, its start and stop date of enrollmnet, type of school and degree 
  working towards & school loop number;
STOP=-4;
do i=1 to dim(degre);
   if stpcm(i)>STOP then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=1;
   end;
   if stpcm(i)=STOP & sch in (4,5,6) & codes(i)=sch & deg in (1,3,4,5,6,10) & degre(i)=deg then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=2;
   end;
   if 0<stpcm(i)<STOP & 0<cdths<STOP & STOP=doicm & 0<STRT<strcm(i) & 0<cdths<=strcm(i)
   &  codes(i) in (4,5,6) & sch in (1,2,3) 
   &  degre(i) in (1,3,4,5,6,10) & deg not in (1,3,4,5,6,10) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=3.1;
   end;
   if 0<stpcm(i)<STOP & 0<cdtgd<STOP & STOP=doicm & 0<STRT<strcm(i) & 0<cdtgd<=strcm(i)
   &  codes(i) in (4,5,6) & sch in (1,2,3) 
   &  degre(i) in (1,3,4,5,6,10) & deg not in (1,3,4,5,6,10) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=3.2;
   end;
   if stpcm(i)=STOP & codes(i) in (5,6) & sch=4 & degre(i) in (1,3,4,5,6,10) & deg in (1,3,4,5,6,10) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=4;
   end;
   if stpcm(i)=STOP & codes(i)=6 & sch=5 & degre(i) in (1,3,4,5,6,10) & deg in (1,3,4,5,6,10) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=4;
   end;
   if stpcm(i)=STOP & codes(i) in (5,6) & sch in (5,6) & degre(i) in (4,5,6,10) & deg in (1,3) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=5;
   end;
   if stpcm(i)=STOP & codes(i) in (4,5,6) & sch in (1,2,3) & (HSD=1|GED=1) then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=6;
   end;
   if 0<stpcm(i)<=STOP & codes(i)in (1,2,3) & sch in (1,2,3) & STOP=doicm & strcm(i)>=STRT>0 then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=7;
   end;
   if stpcm(i)=STOP & STOP=doicm & 0<STRT<strcm(i) 
   &  codes(i) in (4,5,6) & sch in (4,5,6) 
   &  degre(i) in (1,3,4,5,6,10) & deg not in (1,3,4,5,6,10) then do;
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=8;
   end;
end;
do i=1 to dim(degre);
   if stpcm(i)=STOP & codes(i) in (1,2,3) & sch in (4,5,6) & HSD=0 & GED=0 then do;
      STOP=stpcm(i);
      STRT=strcm(i);
      sch=codes(i);
      deg=degre(i);
      rosnum=i;
      STOP_loc=9;
   end;
end;

if STOP>0 then diff=doicm-STOP;
do i=1 to dim(degre);
   if rosnum=i then do;
      if STOP=doicm & stpcm(i)=doicm & reasn(i)>-4 then diff=10000;
   end;
end;
do i=1 to dim(degre);
   if strcm(i)>=-3 & stpcm(i)>=-3 then lastloopnum=i;
end;

* Whether the last school attended was High School or College, and if the latter then for what degree?;
if sch in (-1,-2,-3) then lastsch=-3;
if sch in (1,2,3) then lastsch=1;
if sch in (4,5,6) and deg in (1,3,4,5,6,10) then lastsch=2;
if sch in (4,5,6) and deg in (2,7,8,999,11,12) then lastsch=2.1; 
if sch in (4,5,6) and deg in (9, 13) then lastsch=2.2; 
if sch in (4,5,6) and deg in (-1,-2,-3) then lastsch=2.3;
if sch in (4,5,6) and deg=-4 then lastsch=2.4;
   
* - When R attended college (in a degree program) in a previous round;
do i=1 to dim(encatR);
   if encatR(i) in (4,5,6,7,9,10,11) & degR(i)>=1 then prevcoll=1;
   if encatR(i) in (4,5,6,7,9,10,11) & degR(i)<1 then do;
      prevcoll=1;
      chk_commP=1;
      if hsr18>-4|gdr18>-4 then chk_commP=2;
   end;
end;

* - When R attended college (in a degree program) in a previous round and did not correct HGA as of 
     last interview (e2806) to <13 i.e. accepts being in college as of last interview;	 
do i=1 to dim(encatR); 
   if (e2806r19=-4|e2806r19>=13) & encatR(i) in (4,5,6,7,9,10,11) & (hsR(i)>-4|gdR(i)>-4) then prevcoll=1;
   if (e2806r19=-4|e2806r19>=13) & encatR(i) in (4,5,6,7,9,10,11) & hsR(i)=-4 & gdR(i)=-4 then do;
      prevcoll=1;
      chk_commP=1;
      if 0<CDTHS<=doicmR(i) then chk_commP=2;
      if 0<CDTGD<=doicmR(i) then chk_commP=2;
   end;
end;


* - When R attended college (in a degree program) in this round;
do i=1 to dim(scode);
   if scode(i) in (4,5,6) & e27337(i) in (1,3,4,5,6,10) then currcoll=1;
   if scode(i) in (4,5,6) & e27337(i) not in (2 9) then currcoll_1=1; 
end;
if hsd=0 & ged=0 & currcoll=1             then chk_comm=1;
if hsd=0 & ged=0 & currcoll=1 & clg_ok=-4 then clg_ok=0;
if (hsd=1|ged=1) & currcoll=1             then clg_ok=1;
if prevcoll=1|currcoll=1                  then somecoll=1;
 
* Grade information from loops;
hgaloop=e8416r19_11;
do i=2 to dim(gratnd);
   if gratnd(i)>hgaloop then do;
      hgaloop=gratnd(i);
   end;
end;
if (1<=e2857r19<=12) & HSD=0 & GED=0 then hgsch=1;
do i=1 to dim(scode);
   if scode(i) in (1,2,3) then attsch=1;
end;
do i=1 to dim(e27337);
   if e27337(i) in (1,3) then college=1;
   if e27337(i) in (4,5,6,10) then college=2;
   if e27337(i) in (-1,-2,-3) then college=-3;
end;

if 0<=e2857r19<e3112r19<95 then hgc_hga=1;
if (0<=e2857r19<12) & e3112r19=12 then hgc_hga=2;
if 0<=e2857r19<=12<e3112r19<95 & hsd=0 & ged=0 then hgc_hga=3.1;
if 0<=e2857r19<=12<e3112r19<95 & (hsd=1|ged=1) then hgc_hga=3.2;
if 12<e2857r19<e3112r19<95 then hgc_hga=4;

********************************************************************************************************   
***                       (I) CREATED VARIABLE - ENROLLMENT STATUS (ENCAT)                           ***
********************************************************************************************************;

*** [IA] Determining whether the respondent is enrolled or not;    
    if diff=0 then ENROLL=1;
    if diff>0 then ENROLL=0;
    if -3<=STOP<=-1 then ENROLL=0;
    if e3877A1r19=0 then ENROLL=0;
  
       do i=1 to dim(scode);
          if scode(i) in (4,5,6) then chk_enr2=0;
       end;
       if HSD=1 & ENROLL=1 & chk_enr2 ne 0 then do;
          chk_enr2=1;
          ENROLL=0;
       end; 

*** ENRollx;
    ** Computing ENROLL by another method - ENROLLx;
    if e3877A1r19=0 then enrollx=0;
    if e4795r19=1 & e4951r19=0 then enrollx=1;
    if e4795r19=0 then do;
       if e1605r19=-4 & e4951r19=0 then enrollx=0;
       if e1605r19=1 then do;
          if e1615r19_1=1 & e4951r19=0 then enrollx=1;
          if e1615r19_1=0 & e1627r19_1=0 & e4951r19=0 then enrollx=0;
       end;
       if e1605r19=0 and e4951r19=0 then enrollx=0;
    end;
    if (e4951r19=1 or e3877A1r19=1) then do;
       do i=1 to dim(e6784);
          if e6784(i)=1 & e7192(i)=0 then enrollx=1;
       end;
       do i=1 to dim(e6784);
         if e6938(i)=0 & e7192(i)=0 then enrollx=0;
       end;
       do i=1 to dim(e6784);
          if e6784(i)=0 & e7192(i)=0 then do;
             if e6943(i)=1 then enrollx=1;
          end;
       end;
       do i=1 to dim(e6784);
          if e7142(i)=0 & e7192(i)=0 then enrollx=0;
       end;
    end;

*** change "enroll" after going through the cases where "enroll" disagrees with "enrollx";
	oldenroll=enroll;
  if oldenroll=0 & enrollx=1 & diff=10000 & rosnum>=6 then enroll=1;
  
*** (IB) Determining the sub-categories of not enrolled;

    if ENROLL=0 then do;
       if (GED<=0) & (HSD<=0) then ENCAT=1;
       if GED=1 then ENCAT=2;
       if HSD=1 then ENCAT=3;
       if prevcoll=1 then ENCAT=4;
	   if currcoll=1 & ((13<=e2857r19<=20)|e3112r19>=12|HSD=1|GED=1|somecoll=1) then ENCAT=4;
       if CDTAA>-4 then ENCAT=5;
       if CDTBA>-4 then ENCAT=6;
       if CDTMA>-4|CDTDC>-4|CDTPF>-4 then ENCAT=7;
    end;

*** (IC) Determining the sub-categories of enrolled;

    if ENROLL=1 then do;

       if lastsch=1 then do;
          if CDTHS>0 & e3112r19=12 then flaghs=1;
          if (1<=e2857r19<=12) & HSD<=0 & GED<=0 then ENCAT=8;
          if e2857r19=13 & HSD=0 & GED=0 then ENCAT=8;
          if e2857r19=95 & HSD=0 & GED=0 then do;
             ENCAT=8;
             ungraded=1;
          end;
       end;
       if lastsch=2 then do; 
          if sch=4 & deg in (1,3,4,5,6,10) & ((13<=e2857r19<95)|e3112r19>=12|GED=1|HSD=1|clg_ok=1) 
          then ENCAT=9;
          if sch=5 & deg in (1,3,4,5,6,10) & ((13<=e2857r19<95)|e3112r19>=12|GED=1|HSD=1|clg_ok=1) 
          then ENCAT=10;
          if sch in (5,6) & deg in (4,5,6,10)     & ((16<e2857r19<95)|e3112r19>=16) then ENCAT=11;
          if sch in (5,6) & deg in (4,5,6,10)     & CDTBA>-4 then ENCAT=11;
          if sch=6 and ENCAT ne 11 then gradsch=1;
		  if (1<=e2857r19<=12) & HSD=0 & GED=0 & somecoll~=1 then do; 
             ENCAT=8;
             flagcoll=1;
          end;
       end;
       if lastsch>2 then do;
          if GED=0 & HSD=0 & somecoll=0 then ENCAT=8;
          if currcoll=0 & prevcoll=1 then do;
             ENCAT=4;
             if CDTAA>-4 then ENCAT=5;
             if CDTBA>-4 then ENCAT=6;
             if CDTMA>-4|CDTDC>-4|CDTPF>-4 then ENCAT=7;
		  end;
          if currcoll=1 & (HSD=1|GED=1|clg_ok=1) then do;
             ENCAT=4;
             if CDTAA>-4 then ENCAT=5;
             if CDTBA>-4 then ENCAT=6;
            if CDTMA>-4|CDTDC>-4|CDTPF>-4 then ENCAT=7;
          end;
       end;
       if lastsch=-3 then do;
          if (HSD=1|GED=1|clg_ok=1) & currcoll=1 then ENCAT=4;
		  if prevcoll=1 then ENCAT=4;
          if CDTAA>-4               & somecoll=1 then ENCAT=5;
          if CDTBA>-4               & somecoll=1 then ENCAT=6;
          if (CDTMA>-4|CDTDC>-4|CDTPF>-4) & somecoll=1 then encat=7; 
       end;
       if GED=1 & HSD=0 & somecoll=0 then ENCAT=2;
       if HSD=1 & somecoll=0 then ENCAT=3;
    end;
    if CDTHS>0 & doicm=CDTHS & ENCAT in (-3,1,2,8) then do;
       ENCAT=3;
       same_mth=1;
    end;  
    if CDTGD>0 & doicm=CDTGD & ENCAT in (-3,1,8) then do;
       ENCAT=2;
       same_mth=1;
    end;  
    if CDTAA>0 & doicm=CDTAA & ENCAT in (-3,1,2,8,3,4,9) then do;
       ENCAT=5;
       same_mth=1;
    end;  
    if CDTBA>0 & doicm=CDTBA & ENCAT in (-3,1,2,8,3,4,5,10) then do;
       ENCAT=6;
       same_mth=1;
    end;  
    if ((CDTMA>0 & doicm=CDTMA)|(CDTDC>0 & doicm=CDTDC)|(CDTPF>0 & doicm=CDTPF)) & ENCAT~=7 then do;
       ENCAT=7;
       same_mth=1;
    end;
    if ENROLL=1|(ENROLL=0 & e3877A1r19~=0) then do; 
       if lastsch=-3 & ENCAT<0 then do;
          ENCAT=-3;
          reason=1;
       end;
       if INV2=1 then do; 
          flagcoll=-3;
          college=-3;
          if enroll=0 & somecoll=0 & lastsch=2.3 then do;
             ENCAT=-3;
             reason=2.2;
          end; 
       end;
	  if (HSD=1|GED=1) & (13<=e2857r19<95) & (12<=e3112r19<95) then do; 
          tmpvar1=ENCAT;
          tmpvar2=reason;
          ENCAT=-3;
          reason=3;
          do i=1 to dim(scode);
             if scode(i) in (-1,-2,-3,4,5,6) | prevcoll=1 then do; 
                ENCAT=tmpvar1;
                reason=tmpvar2;
             end;
          end;
       end;   
       if (13<=e2857r19<=20) & GED=0 & HSD=0 & clg_ok~=1 & currcoll=1 & prevcoll~=1 then do; 
          ENCAT=-3;
          reason=5;
       end;
       if rosprb1=1 & ENCAT=-3 & reason=. then reason=6;  
    end;

********************************************** SECTION II **********************************************;
   if ENCAT in (1,2,3,4,5,6,7) & ENROLL~=0 then do;
      ENROLL=0;
      enr_chg=2;
   end;
   if ENCAT in (8,9,10,11) & ENROLL~=1 then do;
      ENROLL=1;
      enr_chg=3;
   end;
  
subsitm=0;  
subhgam=0;  
subprev=0;  
setto12=0;  
dateitm=0;  
disagre=0;  
datedeg=0;  

********************************************************************************************************
***            [II] CREATED VARIABLE - HIGHEST GRADE COMPLETED AS OF THE SURVEY DATE (GRSURV)        ***
********************************************************************************************************;
       GRSURV=GRSURVP; LOCATOR=1;
       GRAUG=GRAUGP; LOCA=1;
       if ENCAT in (4,5,6,7,9,10,11) & e3112r19 in (1,2,3,4,5,6) then do;
          inclg_lowHGC=1;
          e3112r19_imp=e3112r19+12;
       end;
       
***** For those who are asked of 3112;
	if (e3112r19>12 & (currcoll_1=1 or prevcoll=1)) or (e3112r19=12 & cdths ne hsr18) or (0<=e3112r19<12 & attsch=1) or (-4<e3112r19<0 & e3877A1r19~=0)  then do;
       grsurv=e3112r19; locator=2;
       if e3112r19<=12|e3112r19=95 then do;  GRAUG=e3112r19; loca=2; end;  
       if 0<=GRSURVP<e2857r19<e3112r19 then do;
          GRSURV=grsurvP;
          LOCATOR=4.13;
          LOCA=4.13;
       end;
       if e2857r19>e3112r19+1 & e3112r19>GRSURVP>=0 then gr_ncomp1=3;
       if e2857r19>e3112r19+1 & 0<=e3112r19<GRSURVP then gr_ncomp1=4;       
       if 0<=e3112r19<=grsurvP<95 then do;
          GRSURV=grsurvP;
          LOCATOR=4.3;
          LOCA=4.3;
       end;       
       if ENCAT in (4,5,6,7,9,10,11) & 0<=e3112r19<12 then do;
          if e3112r19_imp>12 then GRSURV=e3112r19_imp;
          else inclg_lt12=1;
          LOCATOR=5.2;
       end;       
       if currcoll=1 & 0<=grsurvP<95 & 0<=e3112r19<95 then inclgCI_grchg=e3112r19-grsurvP;
       if currcoll=0 & prevcoll=1 & encatP in (4,5,6,7,9,10,11) & 0<=grsurvP<95 & 0<=e3112r19<95 
       then inclgDLI_grchg=e3112r19-grsurvP;

    ** check on disagre;
       if 0<grsurvP<95 & 0<GRSURV<grsurvP then disagre=1;       
       if disagre=1 & (hsrP>-4|gdrP>-4) & GRSURV<12 & grsurvP>=12 then do;
          disagre=0.5;
          subsprev=1;
          GRSURV=grsurvP;
          LOCATOR=6.10;
       end;      
       if disagre=1 then do;   
	      if 1<=dli_rnd<=15 then rnd_dif= YEAR-(1996 + dli_rnd)+1;
		  else if dli_rnd>15 then rnd_diff= YEAR-(2011 + (dli_rnd -15)*2)+1;
          sitm_pr=e3112r19-grsurvP;         
          if ENCAT in (1,8,-3) then do;
             if ENCAT=-3 then do;
                GRSURV=-3;
                if e3112r19<=12|e3112r19=95 then GRAUG=-3;
                LOCATOR=6.11;
                LOCA=6.11;
             end;
             if 0<=e3112r19<=12 & (0<=sitm_pr<=rnd_dif|grsurvP=95) then do;
                subsitm=1;
                GRSURV=e3112r19;
                LOCATOR=6.12; 
                GRAUG=-3;
                LOCA=6.12;
             end;  
          end;      
          if 12<=grsurvP<95 & ENCAT in (4,5,6,7,9,10,11) then do; 
             GRSURV=grsurvP;
             subprev=1;
             LOCATOR=6.21;
           if currcoll=1 then do; 
             subsitm=1;
             if 0<=sitm_pr<=rnd_dif then do;
                GRSURV=e3112r19;
                LOCATOR=6.22;
             end;
             if e3112r19_imp>grsurvP then do;
                GRSURV=e3112r19_imp;
                LOCATOR=6.23;
             end; 
           end;         
          end;         
       end;      
       if 0<grsurvP<95 & 0<GRSURV<grsurvP then do;
          disagre=3;
       end;
       
    ** check again;
       if (hsrP>-4|gdrP>-4) & GRSURV~=grsurvP & 0<GRSURV<12 then do;
          if attsch~=1 & grsurvP=grsurvP_no3061 then do;
             GRSURV=grsurvP;
             LOCATOR=9.1;
             LOCA=9.1;
          end;
          if attsch=1|grsurvP~=grsurvP_no3061 then do; 
             LOCATOR=9.2;
          end;
       end;   
       
    ** GRAUG; 
       if GRAUG=-3 & GRSURV>0 then do;
          if 0<STOP<MONYR & sch in (1,2,3) then do;
             GRAUG=GRSURV;
             LOCA=10.4;
          end;
       end;
       if GRSURV=grsurvP & (0<=grsurvP<=12|grsurvP=95) then do; 
          GRAUG=grsurvP;
          LOCA=12.1;
       end;
       if GRAUG=grsurvP & grsurvP=12 & (cdths>MONYR>0) then do;
             GRAUG=-3;
             LOCA=12.4;
       end;
       if (hsrP>-4|gdrP>-4) & 0<=grsurvP<=12 & GRAUG<grsurvP then do;
             subprev=1;
             GRAUG=grsurvP;
             LOCA=13.11;
       end;
	   if GRAUG<graugP then do;
          if 0<=graugP<=12 then do;
             subprev=1;
             GRAUG=graugP;
             LOCA=13.12;
          end;
          if grsurvP<0 & graugP<0 then do; 
             GRAUG=-3;
             LOCA=13.13;
          end;
       end;

    ** If R reports a HGC>12 but R is not in a college-degree program we assign the HGC in highschool
       as the HGC received.;
       if ENCAT in (1,2,3,8,-3) & (12<GRSURV<95|(12<e3112r19<95 & GRSURV=-3)) then do; 
             whyover12=1;
             if (12<GRSURV<95 & 0<grsurvP<=12)|(GRSURV<grsurvP &  0<grsurvP<=12) then do;
                GRSURV=grsurvP;
                GRAUG=grsurvP;
                LOCATOR=13.42;
                LOCA=13.42;
             end;
             if (12<GRSURV<95 & 0<grsurvP_no3061<=12)|(GRSURV<grsurvP_no3061 & 0<grsurvP_no3061<=12) then do;
                GRSURV=grsurvP_no3061;
                GRAUG=grsurvP_no3061;
                LOCATOR=13.5;
                LOCA=13.5;
             end;
             if (12<GRSURV<95 & 0<e3112r19<=12)|(GRSURV<e3112r19 &  0<e3112r19<=12) then do;
                subsitm=1;
                GRSURV=e3112r19;
                GRAUG=-3;
                LOCATOR=13.6;
                LOCA=13.61;
                if GRSURV=grsurvP then do;
                   GRAUG=grsurvP;
                   LOCA=13.62;
                end;
                if GRSURV=grsurvP_no3061 then do;
                   GRAUG=grsurvP_no3061;
                   LOCA=13.63;
                end;
             end;
       end;
       
    ** flag these cases;
       if 12<GRSURV<95 & ENCAT in (1,2,3,8,-3) then LOCATOR=13.7;
       if 12<GRAUG<95 & ENCAT in (1,2,3,8,-3) then LOCA=13.7;

    ** more on GRAUG;
       if grsurvP=12 & GRSURV>=12 & GRAUG~=12 then do;
          GRAUG=12;
          LOCA=16;
       end;
       if grsurvP<=12 & GRSURV>=12 & attsch=0 & (GRAUG=.|GRAUG=-3) & ENCAT in (4,5,6,7,9,10,11) then do;
          GRAUG=grsurvP;
          LOCA=17;
       end;
       if 12<grsurvP<95 then do;
          GRAUG=graugP;
          LOCA=18;
       end;
       if graugP=12 then do;
          GRAUG=12;
          LOCA=19;
       end;

    ** attsch=0;
       if LOCATOR~=15 then do; 
          if attsch=0 & e3877A1r19~=0 & 0<=e3112r19<=12 & 0<=grsurvP<GRSURV<=12 then do;
             GRSURV=grsurvP;
             GRAUG=GRSURV;
             LOCATOR=20.1;
             LOCA=20.1;
          end;
          if attsch=0 & e3877A1r19~=0 & 12<e3112r19<95 & 0<=grsurvP_no3061<GRAUG<=12 then do;
             GRAUG=grsurvP_no3061;
             LOCA=20.2;
          end;
       end;    
    end;
       
***** for those who were HE in the DLI and not enrolled at or since DLI;
    if e3877A1r19=0 then do;  
      if locatorr18=15 then do;
        grsurv=cvc_hgcr18;
        locator=15;
      end;
      if locaP=15 then do;
        graug=graugP;
        loca=15;
      end;
    end;
       

********************************************************************************************************
***           [IV] CREATED VARIABLE - HIGHEST DEGREE RECEIVED AS OF THE SURVEY DATE (DEGSURV)        ***
********************************************************************************************************;
    DEGSURV=0;
   
    ** GED;
    if GED=1 then DEGSURV=1;
    if GED=-3 then DEGSURV=-3;
   
    ** High School Diploma;
    if HSD=1 then DEGSURV=2;
    if HSD=-3 then DEGSURV=-3;
   
    ** Junior College or two-year Associate Degree;
    if CDTAA>-4 then DEGSURV=3;

    ** Bachelor's Degree;
    if CDTBA>-4 then DEGSURV=4;
        
    ** Master's Degree;
    if CDTMA>-4 then DEGSURV=5;
    
    ** Doctoral Degree;
    if CDTDC>-4 then DEGSURV=6;
    
    ** Professional Degree;
    if CDTPF>-4 then DEGSURV=7;
    
    ** If degree received cannot determine what degree received;
    do i=1 to dim(e23450);
	   if e23450(i) in (-1, -2, -3) & DEGSURV not in (4 5 6 7) then DEGSURV=-3;
    end;
    if 0<=DEGSURV<cvc_hdgr18 then prev_deg=1; 

********************************************************************************************************
***          [V] CREATED VARIABLE - HIGHEST DEGREE COMPLETED AS OF JUNE 30, 2001 (DEGAUG)           ***
********************************************************************************************************;

    DEGAUG=0;
   
    ** GED;
    if 0<CDTGD<=MONYR then DEGAUG=1;
    if CDTGD in (-3, -2, -1) then DEGAUG=-3;
   
    ** High School Diploma;
    if 0<CDTHS<=MONYR then DEGAUG=2;
    if CDTHS in (-3, -2, -1) then DEGAUG=-3;
   
    ** Junior College or 2-year Associate Degree;
    if 0<CDTAA<=MONYR then DEGAUG=3;
    if CDTAA in (-3, -2, -1) then DEGAUG=-3;
   
    ** Bachelor's Degree;
    if 0<CDTBA<=MONYR then DEGAUG=4;
    if CDTBA in (-3, -2, -1) then DEGAUG=-3;
   
    ** Master's Degree;
    if 0<CDTMA<=MONYR then DEGAUG=5;
    if CDTMA in (-3, -2, -1) then DEGAUG=-3;
   
    ** Doctoral Degree;
    if 0<CDTDC<=MONYR then DEGAUG=6;
    if CDTDC in (-3, -2, -1) then DEGAUG=-3;
   
    ** Professional Degree;
    if 0<CDTPF<=MONYR then DEGAUG=7;
    if CDTPF in (-3, -2, -1) then DEGAUG=-3;
   
    if DEGSURV=-3 then DEGAUG=-3;

    if (DEGSURV=1 & -4<CDTGD<=0)|(DEGSURV=2 & -4<CDTHS<=0)|(DEGSURV=3 & -4<CDTAA<=0)
      |(DEGSURV=4 & -4<CDTBA<=0)|(DEGSURV=5 & -4<CDTMA<=0)|(DEGSURV=6 & -4<CDTDC<=0)
      |(DEGSURV=7 & -4<CDTPF<=0) then do;
      datedeg=1;
      DEGAUG=-3;
    end;
    if DEGAUG~=DEGSURV & DEGSURV=degsurvP & DEGSURV>=0 then do; 
       DEGAUG=degsurvP;
    end;
    
    if (cdtgd=gdr18 & cdths=hsr18 & cdtaa=aar18 & cdtba=bar18 & cdtma=mar18 & cdtpf=pfr18
	   & cdtdc=dcr18) then do;
	  if he18_deg ne . then do;
	    he19_deg=degsurv;
	    degsurv=-3;
	    degaug=-3;
	    if encatr18=-3 & encat in (1,2,3,5,6,7) then do;
	      he19_en=encat;
	      encat=-3;
	    end;
	  end;
	  else if degsurv ne degsurvP then chk21=1;
	end;
	
if ENCAT    in (-1,-2) then ENCAT=-3;
if GRSURV   in (-1,-2) then GRSURV=-3;
if GRAUG   in (-1,-2) then GRAUG=-3;
if DEGSURV  in (-1,-2) then DEGSURV=-3;
if DEGAUG  in (-1,-2) then DEGAUG=-3;


***** generate GRSURVF which is used to generate HGC in LEFT_HS program;

grsurvFP=grsurvFr18;

*** Create grsurvF;
    grsurvF=grsurvFP;
    locF=6;
    
     if (e3112r19>12 & (currcoll_1=1 or prevcoll=1)) or (e3112r19=12 & cdths ne hsr18) or (0<=e3112r19<12 & attsch=1) or (-4<e3112r19<0 & e3877A1r19~=0)  then do;
       if hsrP=-4 & (grsurvFP<12|grsurvFP=95) & (GRSURV<=12|GRSURV=95) then do;
          grsurvF=GRSURV;
          locF=1;
       end;
       if hsrP=-4 & (grsurvFP<12|grsurvFP=95) & 12<GRSURV<95 then do;
             grsurvF=grsurvFP;
             locF=3;
       end;
       if hsrP>-4|gdrP>-4|grsurvFP=12 then do;
          grsurvF=grsurvFP;
          locF=4.1;
          if grsurvFP=-3 then do;
           if 0<grsurv<=12 then do;
            grsurvF=grsurv;
            locF=4.21;
           end;
           else if 0<graug<=12 then do;
            locF=4.22;
           end;
          end;    
          if grsurvFP<grsurv<=12 then do;
           grsurvF=grsurv;
           locF=4.3;
          end;       
       end;
	   if hsrP=-4 & gdrP=-4 & grsurvFP<12 & ENCAT in (1,2,3,8,-3) & (GRSURV<=12|GRSURV=95) then do; 
          grsurvF=GRSURV;
          locF=5;
       end;       
       if LOCATOR~=15 & attsch=0 & e3877A1r19~=0 & 0<=e3112r19<=12 & 0<=grsurvP<GRSURV<=12 & locF in (1,5) then do;
          grsurvF=GRSURVP;
          locF=7;
       end;    
    end;

***** Finalize two cvc_ variables;
grsurv_cvc=grsurv;
degsurv_cvc=degsurv; 

***** finalize the CV_ variables;
if e3112r19=-5 then do;
   ENROLL=-5;
   ENCAT=-5;
   GRSURV=-5;
   GRAUG=-5;
   DEGSURV=-5;
   DEGAUG=-5;
   GED=-5;
   HSD=-5;
   LOCATOR=-5;
   LOCA=-5;
end;

***** flags to check;
if ENCAT in (4,5,6,7,9,10,11) then do;
   if 0<=grsurv_cvc<12 then chk1=1;
   if grsurv_cvc=95 then chk1=2;
end;
if chk1=1 then do; 
 if encat in (5,6,7) then chk1enc=1;
 if encat in (4,9,10,11) & ged=1 then chk1ged=0;
 if encat in (4,9,10,11) & ged ne 1 then chk1ged=1;
end;
if ENCAT in (1,2,3,8,-3) then do;
  if 12<grsurv_cvc<95 then chk2=1;
  if grsurv_cvc=95 then chk2=2;
end;
if degsurv_cvc=0 & ENCAT in (2,3,4,5,6,7,9,10,11) then chk3=1;
if degsurv_cvc=1 & ENCAT in (1,8,3,5,6,7) then chk3=2;
if degsurv_cvc=2 & ENCAT in (1,8,2,5,6,7) then chk3=3;
if degsurv_cvc=3 & ENCAT in (1,8,2,3,6,7,4) then chk3=4;
if degsurv_cvc=4 & ENCAT in (1,8,2,3,5,7,4) then chk3=5;
if degsurv_cvc in (5,6,7) & ENCAT in (1,8,2,3,5,6,4) then chk3=6;
if 0<=e2857r19<grsurv<95 then do;
   if 0<=e2857r19<grsurvP<95 & e3877A1r19~=0 then chk4=1.1; 
   if 0<=e2857r19<e3112r19<95 then chk4=1.3;
   if hsd=1 & grsurv_cvc=12 then chk4=.;
end;
if 0<=e2857r19<6 & ENCAT in (4,5,6,7,9,10,11) then z=e2857r19+12;
if z=. then chk4z=chk4;
if 0<=z<grsurv_cvc then do;
   if 0<=z<grsurvP & e3877A1r19~=0 then chk4z=1.1;
   if 0<=z<e3112r19 then chk4z=1.3;
   if hsd=1 & grsurv_cvc=12 then chk4z=.;
end;
if ENCAT=-3 & grsurv_cvc~=-3 then chk5=1;
if ENCAT~=-3 & grsurv_cvc=-3 & LOCATOR~=15 then chk5=2;
if ENCAT in (4,5,6,7,9,10,11) & currcoll=0 & 0<=grsurvP<grsurv_cvc & ever_24yrinst~=1 then chk6=1;
if 0<grsurv_cvc<grsurvP<95 then disagre=4;

if cdths>-4 & 0<=grsurv_cvc<12 & degsurv_cvc ne -3 then chk31=1;
if cdths=-4 & grsurv_cvc=12 & degsurv_cvc ne -3 then chk32=1;  
if degsurv_cvc>2 & 0<=grsurv_cvc<=12 then chk33=1; 

if e3877A1r19=0 & grsurv_cvc ne cvc_hgcr18 then chk11=1; 
if 0<grsurv_cvc<=12 & graug ne grsurv_cvc & graug ne -5 then chk12=1;
if 0<grsurv_cvc<=12 & grsurvF ne grsurv_cvc then chk13=1;
if (e3112r19 ne -5 & grsurvF ne graug) or (e3112r19=-5 & grsurvF ne graugP) then chk14=1;
  if (e3112r19 ne -5 & grsurvF ne graug) then chk14=1.1;
  if (e3112r19=-5 & grsurvF ne graugP) then chk14=1.2;

if degsurv=2 & degaug not in (2,-5) then chk22=1;

***** finalize the CV_ variables;
if e3112r19=-5 then do;
   ENROLL=-5;
   ENCAT=-5;
   GRSURV=-5;
   GRAUG=-5;
   DEGSURV=-5;
   DEGAUG=-5;
   GED=-5;
   HSD=-5;
   LOCATOR=-5;
   LOCA=-5;
end;